guile.m4 14 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360
  1. ## Autoconf macros for working with Guile.
  2. ##
  3. ## Copyright (C) 1998,2001, 2006, 2010, 2012, 2013, 2014 Free Software Foundation, Inc.
  4. ##
  5. ## This library is free software; you can redistribute it and/or
  6. ## modify it under the terms of the GNU Lesser General Public License
  7. ## as published by the Free Software Foundation; either version 3 of
  8. ## the License, or (at your option) any later version.
  9. ##
  10. ## This library is distributed in the hope that it will be useful,
  11. ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13. ## Lesser General Public License for more details.
  14. ##
  15. ## You should have received a copy of the GNU Lesser General Public
  16. ## License along with this library; if not, write to the Free Software
  17. ## Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  18. ## 02110-1301 USA
  19. # serial 10
  20. ## Index
  21. ## -----
  22. ##
  23. ## GUILE_PKG -- find Guile development files
  24. ## GUILE_PROGS -- set paths to Guile interpreter, config and tool programs
  25. ## GUILE_FLAGS -- set flags for compiling and linking with Guile
  26. ## GUILE_SITE_DIR -- find path to Guile "site" directory
  27. ## GUILE_CHECK -- evaluate Guile Scheme code and capture the return value
  28. ## GUILE_MODULE_CHECK -- check feature of a Guile Scheme module
  29. ## GUILE_MODULE_AVAILABLE -- check availability of a Guile Scheme module
  30. ## GUILE_MODULE_REQUIRED -- fail if a Guile Scheme module is unavailable
  31. ## GUILE_MODULE_EXPORTS -- check if a module exports a variable
  32. ## GUILE_MODULE_REQUIRED_EXPORT -- fail if a module doesn't export a variable
  33. ## Code
  34. ## ----
  35. ## NOTE: Comments preceding an AC_DEFUN (starting from "Usage:") are massaged
  36. ## into doc/ref/autoconf-macros.texi (see Makefile.am in that directory).
  37. # GUILE_PKG -- find Guile development files
  38. #
  39. # Usage: GUILE_PKG([VERSIONS])
  40. #
  41. # This macro runs the @code{pkg-config} tool to find development files
  42. # for an available version of Guile.
  43. #
  44. # By default, this macro will search for the latest stable version of
  45. # Guile (e.g. 2.2), falling back to the previous stable version
  46. # (e.g. 2.0) if it is available. If no guile-@var{VERSION}.pc file is
  47. # found, an error is signalled. The found version is stored in
  48. # @var{GUILE_EFFECTIVE_VERSION}.
  49. #
  50. # If @code{GUILE_PROGS} was already invoked, this macro ensures that the
  51. # development files have the same effective version as the Guile
  52. # program.
  53. #
  54. # @var{GUILE_EFFECTIVE_VERSION} is marked for substitution, as by
  55. # @code{AC_SUBST}.
  56. #
  57. AC_DEFUN([GUILE_PKG],
  58. [PKG_PROG_PKG_CONFIG
  59. _guile_versions_to_search="m4_default([$1], [2.0 1.8])"
  60. if test -n "$GUILE_EFFECTIVE_VERSION"; then
  61. _guile_tmp=""
  62. for v in $_guile_versions_to_search; do
  63. if test "$v" = "$GUILE_EFFECTIVE_VERSION"; then
  64. _guile_tmp=$v
  65. fi
  66. done
  67. if test -z "$_guile_tmp"; then
  68. AC_MSG_FAILURE([searching for guile development files for versions $_guile_versions_to_search, but previously found $GUILE version $GUILE_EFFECTIVE_VERSION])
  69. fi
  70. _guile_versions_to_search=$GUILE_EFFECTIVE_VERSION
  71. fi
  72. GUILE_EFFECTIVE_VERSION=""
  73. _guile_errors=""
  74. for v in $_guile_versions_to_search; do
  75. if test -z "$GUILE_EFFECTIVE_VERSION"; then
  76. AC_MSG_NOTICE([checking for guile $v])
  77. PKG_CHECK_EXISTS([guile-$v], [GUILE_EFFECTIVE_VERSION=$v], [])
  78. fi
  79. done
  80. if test -z "$GUILE_EFFECTIVE_VERSION"; then
  81. AC_MSG_ERROR([
  82. No Guile development packages were found.
  83. Please verify that you have Guile installed. If you installed Guile
  84. from a binary distribution, please verify that you have also installed
  85. the development packages. If you installed it yourself, you might need
  86. to adjust your PKG_CONFIG_PATH; see the pkg-config man page for more.
  87. ])
  88. fi
  89. AC_MSG_NOTICE([found guile $GUILE_EFFECTIVE_VERSION])
  90. AC_SUBST([GUILE_EFFECTIVE_VERSION])
  91. ])
  92. # GUILE_FLAGS -- set flags for compiling and linking with Guile
  93. #
  94. # Usage: GUILE_FLAGS
  95. #
  96. # This macro runs the @code{pkg-config} tool to find out how to compile
  97. # and link programs against Guile. It sets four variables:
  98. # @var{GUILE_CFLAGS}, @var{GUILE_LDFLAGS}, @var{GUILE_LIBS}, and
  99. # @var{GUILE_LTLIBS}.
  100. #
  101. # @var{GUILE_CFLAGS}: flags to pass to a C or C++ compiler to build code that
  102. # uses Guile header files. This is almost always just one or more @code{-I}
  103. # flags.
  104. #
  105. # @var{GUILE_LDFLAGS}: flags to pass to the compiler to link a program
  106. # against Guile. This includes @code{-lguile-@var{VERSION}} for the
  107. # Guile library itself, and may also include one or more @code{-L} flag
  108. # to tell the compiler where to find the libraries. But it does not
  109. # include flags that influence the program's runtime search path for
  110. # libraries, and will therefore lead to a program that fails to start,
  111. # unless all necessary libraries are installed in a standard location
  112. # such as @file{/usr/lib}.
  113. #
  114. # @var{GUILE_LIBS} and @var{GUILE_LTLIBS}: flags to pass to the compiler or to
  115. # libtool, respectively, to link a program against Guile. It includes flags
  116. # that augment the program's runtime search path for libraries, so that shared
  117. # libraries will be found at the location where they were during linking, even
  118. # in non-standard locations. @var{GUILE_LIBS} is to be used when linking the
  119. # program directly with the compiler, whereas @var{GUILE_LTLIBS} is to be used
  120. # when linking the program is done through libtool.
  121. #
  122. # The variables are marked for substitution, as by @code{AC_SUBST}.
  123. #
  124. AC_DEFUN([GUILE_FLAGS],
  125. [AC_REQUIRE([GUILE_PKG])
  126. PKG_CHECK_MODULES(GUILE, [guile-$GUILE_EFFECTIVE_VERSION])
  127. dnl GUILE_CFLAGS and GUILE_LIBS are already defined and AC_SUBST'd by
  128. dnl PKG_CHECK_MODULES. But GUILE_LIBS to pkg-config is GUILE_LDFLAGS
  129. dnl to us.
  130. GUILE_LDFLAGS=$GUILE_LIBS
  131. dnl Determine the platform dependent parameters needed to use rpath.
  132. dnl AC_LIB_LINKFLAGS_FROM_LIBS is defined in gnulib/m4/lib-link.m4 and needs
  133. dnl the file gnulib/build-aux/config.rpath.
  134. AC_LIB_LINKFLAGS_FROM_LIBS([GUILE_LIBS], [$GUILE_LDFLAGS], [])
  135. GUILE_LIBS="$GUILE_LDFLAGS $GUILE_LIBS"
  136. AC_LIB_LINKFLAGS_FROM_LIBS([GUILE_LTLIBS], [$GUILE_LDFLAGS], [yes])
  137. GUILE_LTLIBS="$GUILE_LDFLAGS $GUILE_LTLIBS"
  138. AC_SUBST([GUILE_EFFECTIVE_VERSION])
  139. AC_SUBST([GUILE_CFLAGS])
  140. AC_SUBST([GUILE_LDFLAGS])
  141. AC_SUBST([GUILE_LIBS])
  142. AC_SUBST([GUILE_LTLIBS])
  143. ])
  144. # GUILE_SITE_DIR -- find path to Guile "site" directory
  145. #
  146. # Usage: GUILE_SITE_DIR
  147. #
  148. # This looks for Guile's "site" directory, usually something like
  149. # PREFIX/share/guile/site, and sets var @var{GUILE_SITE} to the path.
  150. # Note that the var name is different from the macro name.
  151. #
  152. # The variable is marked for substitution, as by @code{AC_SUBST}.
  153. #
  154. AC_DEFUN([GUILE_SITE_DIR],
  155. [AC_REQUIRE([GUILE_PKG])
  156. AC_MSG_CHECKING(for Guile site directory)
  157. GUILE_SITE=`$PKG_CONFIG --print-errors --variable=sitedir guile-$GUILE_EFFECTIVE_VERSION`
  158. AC_MSG_RESULT($GUILE_SITE)
  159. if test "$GUILE_SITE" = ""; then
  160. AC_MSG_FAILURE(sitedir not found)
  161. fi
  162. AC_SUBST(GUILE_SITE)
  163. ])
  164. # GUILE_PROGS -- set paths to Guile interpreter, config and tool programs
  165. #
  166. # Usage: GUILE_PROGS([VERSION])
  167. #
  168. # This macro looks for programs @code{guile} and @code{guild}, setting
  169. # variables @var{GUILE} and @var{GUILD} to their paths, respectively.
  170. # The macro will attempt to find @code{guile} with the suffix of
  171. # @code{-X.Y}, followed by looking for it with the suffix @code{X.Y}, and
  172. # then fall back to looking for @code{guile} with no suffix. If
  173. # @code{guile} is still not found, signal an error. The suffix, if any,
  174. # that was required to find @code{guile} will be used for @code{guild}
  175. # as well.
  176. #
  177. # By default, this macro will search for the latest stable version of
  178. # Guile (e.g. 2.0). x.y or x.y.z versions can be specified. If an older
  179. # version is found, the macro will signal an error.
  180. #
  181. # The effective version of the found @code{guile} is set to
  182. # @var{GUILE_EFFECTIVE_VERSION}. This macro ensures that the effective
  183. # version is compatible with the result of a previous invocation of
  184. # @code{GUILE_FLAGS}, if any.
  185. #
  186. # As a legacy interface, it also looks for @code{guile-config} and
  187. # @code{guile-tools}, setting @var{GUILE_CONFIG} and @var{GUILE_TOOLS}.
  188. #
  189. # The variables are marked for substitution, as by @code{AC_SUBST}.
  190. #
  191. AC_DEFUN([GUILE_PROGS],
  192. [_guile_required_version="m4_default([$1], [$GUILE_EFFECTIVE_VERSION])"
  193. if test -z "$_guile_required_version"; then
  194. _guile_required_version=2.0
  195. fi
  196. _guile_candidates=guile
  197. _tmp=
  198. for v in `echo "$_guile_required_version" | tr . ' '`; do
  199. if test -n "$_tmp"; then _tmp=.$_tmp; fi
  200. _tmp=$v$_tmp
  201. _guile_candidates="guile-$_tmp guile$_tmp $_guile_candidates"
  202. done
  203. AC_PATH_PROGS(GUILE,[$_guile_candidates])
  204. if test -z "$GUILE"; then
  205. AC_MSG_ERROR([guile required but not found])
  206. fi
  207. _guile_suffix=`echo "$GUILE" | sed -e 's,^.*/guile\(.*\)$,\1,'`
  208. _guile_effective_version=`$GUILE -c "(display (effective-version))"`
  209. if test -z "$GUILE_EFFECTIVE_VERSION"; then
  210. GUILE_EFFECTIVE_VERSION=$_guile_effective_version
  211. elif test "$GUILE_EFFECTIVE_VERSION" != "$_guile_effective_version"; then
  212. AC_MSG_ERROR([found development files for Guile $GUILE_EFFECTIVE_VERSION, but $GUILE has effective version $_guile_effective_version])
  213. fi
  214. _guile_major_version=`$GUILE -c "(display (major-version))"`
  215. _guile_minor_version=`$GUILE -c "(display (minor-version))"`
  216. _guile_micro_version=`$GUILE -c "(display (micro-version))"`
  217. _guile_prog_version="$_guile_major_version.$_guile_minor_version.$_guile_micro_version"
  218. AC_MSG_CHECKING([for Guile version >= $_guile_required_version])
  219. _major_version=`echo $_guile_required_version | cut -d . -f 1`
  220. _minor_version=`echo $_guile_required_version | cut -d . -f 2`
  221. _micro_version=`echo $_guile_required_version | cut -d . -f 3`
  222. if test "$_guile_major_version" -gt "$_major_version"; then
  223. true
  224. elif test "$_guile_major_version" -eq "$_major_version"; then
  225. if test "$_guile_minor_version" -gt "$_minor_version"; then
  226. true
  227. elif test "$_guile_minor_version" -eq "$_minor_version"; then
  228. if test -n "$_micro_version"; then
  229. if test "$_guile_micro_version" -lt "$_micro_version"; then
  230. AC_MSG_ERROR([Guile $_guile_required_version required, but $_guile_prog_version found])
  231. fi
  232. fi
  233. elif test "$GUILE_EFFECTIVE_VERSION" = "$_major_version.$_minor_version" -a -z "$_micro_version"; then
  234. # Allow prereleases that have the right effective version.
  235. true
  236. else
  237. as_fn_error $? "Guile $_guile_required_version required, but $_guile_prog_version found" "$LINENO" 5
  238. fi
  239. else
  240. AC_MSG_ERROR([Guile $_guile_required_version required, but $_guile_prog_version found])
  241. fi
  242. AC_MSG_RESULT([$_guile_prog_version])
  243. AC_PATH_PROG(GUILD,[guild$_guile_suffix])
  244. AC_SUBST(GUILD)
  245. AC_PATH_PROG(GUILE_CONFIG,[guile-config$_guile_suffix])
  246. AC_SUBST(GUILE_CONFIG)
  247. if test -n "$GUILD"; then
  248. GUILE_TOOLS=$GUILD
  249. else
  250. AC_PATH_PROG(GUILE_TOOLS,[guile-tools$_guile_suffix])
  251. fi
  252. AC_SUBST(GUILE_TOOLS)
  253. ])
  254. # GUILE_CHECK -- evaluate Guile Scheme code and capture the return value
  255. #
  256. # Usage: GUILE_CHECK_RETVAL(var,check)
  257. #
  258. # @var{var} is a shell variable name to be set to the return value.
  259. # @var{check} is a Guile Scheme expression, evaluated with "$GUILE -c", and
  260. # returning either 0 or non-#f to indicate the check passed.
  261. # Non-0 number or #f indicates failure.
  262. # Avoid using the character "#" since that confuses autoconf.
  263. #
  264. AC_DEFUN([GUILE_CHECK],
  265. [AC_REQUIRE([GUILE_PROGS])
  266. $GUILE -c "$2" > /dev/null 2>&1
  267. $1=$?
  268. ])
  269. # GUILE_MODULE_CHECK -- check feature of a Guile Scheme module
  270. #
  271. # Usage: GUILE_MODULE_CHECK(var,module,featuretest,description)
  272. #
  273. # @var{var} is a shell variable name to be set to "yes" or "no".
  274. # @var{module} is a list of symbols, like: (ice-9 common-list).
  275. # @var{featuretest} is an expression acceptable to GUILE_CHECK, q.v.
  276. # @var{description} is a present-tense verb phrase (passed to AC_MSG_CHECKING).
  277. #
  278. AC_DEFUN([GUILE_MODULE_CHECK],
  279. [AC_MSG_CHECKING([if $2 $4])
  280. GUILE_CHECK($1,(use-modules $2) (exit ((lambda () $3))))
  281. if test "$$1" = "0" ; then $1=yes ; else $1=no ; fi
  282. AC_MSG_RESULT($$1)
  283. ])
  284. # GUILE_MODULE_AVAILABLE -- check availability of a Guile Scheme module
  285. #
  286. # Usage: GUILE_MODULE_AVAILABLE(var,module)
  287. #
  288. # @var{var} is a shell variable name to be set to "yes" or "no".
  289. # @var{module} is a list of symbols, like: (ice-9 common-list).
  290. #
  291. AC_DEFUN([GUILE_MODULE_AVAILABLE],
  292. [GUILE_MODULE_CHECK($1,$2,0,is available)
  293. ])
  294. # GUILE_MODULE_REQUIRED -- fail if a Guile Scheme module is unavailable
  295. #
  296. # Usage: GUILE_MODULE_REQUIRED(symlist)
  297. #
  298. # @var{symlist} is a list of symbols, WITHOUT surrounding parens,
  299. # like: ice-9 common-list.
  300. #
  301. AC_DEFUN([GUILE_MODULE_REQUIRED],
  302. [GUILE_MODULE_AVAILABLE(ac_guile_module_required, ($1))
  303. if test "$ac_guile_module_required" = "no" ; then
  304. AC_MSG_ERROR([required guile module not found: ($1)])
  305. fi
  306. ])
  307. # GUILE_MODULE_EXPORTS -- check if a module exports a variable
  308. #
  309. # Usage: GUILE_MODULE_EXPORTS(var,module,modvar)
  310. #
  311. # @var{var} is a shell variable to be set to "yes" or "no".
  312. # @var{module} is a list of symbols, like: (ice-9 common-list).
  313. # @var{modvar} is the Guile Scheme variable to check.
  314. #
  315. AC_DEFUN([GUILE_MODULE_EXPORTS],
  316. [GUILE_MODULE_CHECK($1,$2,$3,exports `$3')
  317. ])
  318. # GUILE_MODULE_REQUIRED_EXPORT -- fail if a module doesn't export a variable
  319. #
  320. # Usage: GUILE_MODULE_REQUIRED_EXPORT(module,modvar)
  321. #
  322. # @var{module} is a list of symbols, like: (ice-9 common-list).
  323. # @var{modvar} is the Guile Scheme variable to check.
  324. #
  325. AC_DEFUN([GUILE_MODULE_REQUIRED_EXPORT],
  326. [GUILE_MODULE_EXPORTS(guile_module_required_export,$1,$2)
  327. if test "$guile_module_required_export" = "no" ; then
  328. AC_MSG_ERROR([module $1 does not export $2; required])
  329. fi
  330. ])
  331. ## guile.m4 ends here