sonyoss-vita-webkit/Tools/TestWebKitAPI/Tests/mac/AttributedString.mm

/*
 * Copyright (C) 2012 Apple Inc. All rights reserved.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * 1. Redistributions of source code must retain the above copyright
 *    notice, this list of conditions and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the above copyright
 *    notice, this list of conditions and the following disclaimer in the
 *    documentation and/or other materials provided with the distribution.
 *
 * THIS SOFTWARE IS PROVIDED BY APPLE INC. AND ITS CONTRIBUTORS ``AS IS''
 * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
 * THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
 * PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL APPLE INC. OR ITS CONTRIBUTORS
 * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
 * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
 * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
 * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
 * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF
 * THE POSSIBILITY OF SUCH DAMAGE.
 */

#import "config.h"
#import "Test.h"

#import "PlatformUtilities.h"
#import "PlatformWebView.h"
#import "WebKitAgnosticTest.h"
#import <wtf/RetainPtr.h>

namespace TestWebKitAPI {

static NSAttributedString *attributedString(WebView *webView, NSRange range)
{
    return [(NSView <NSTextInput> *)[[[webView mainFrame] frameView] documentView] attributedSubstringFromRange:range];
}

static NSAttributedString *attributedString(WKView *wkView, NSRange range)
{
    NSRange actualRange;
    return [wkView attributedSubstringForProposedRange:range actualRange:&actualRange];
}


class AttributedStringTest_CustomFont : public WebKitAgnosticTest {
public:
    template <typename View> void runTest(View);

    // WebKitAgnosticTest
    virtual void didLoadURL(WebView *webView) { runTest(webView); }
    virtual void didLoadURL(WKView *wkView) { runTest(wkView); }

    virtual NSURL *url() const { return [[NSBundle mainBundle] URLForResource:@"attributedStringCustomFont" withExtension:@"html" subdirectory:@"TestWebKitAPI.resources"]; }
};

template <typename View>
void AttributedStringTest_CustomFont::runTest(View view)
{
    NSAttributedString *attrString = attributedString(view, NSMakeRange(0, 5));
    EXPECT_WK_STREQ("Lorem", [attrString string]);
}

TEST_F(AttributedStringTest_CustomFont, WebKit)
{
    runWebKit1Test();
}

TEST_F(AttributedStringTest_CustomFont, WebKit2)
{
    runWebKit2Test();
}

class AttributedStringTest_Strikethrough : public WebKitAgnosticTest {
public:
    template <typename View> void runTest(View);

    // WebKitAgnosticTest
    virtual void didLoadURL(WebView *webView) { runTest(webView); }
    virtual void didLoadURL(WKView *wkView) { runTest(wkView); }

    virtual NSURL *url() const { return [[NSBundle mainBundle] URLForResource:@"attributedStringStrikethrough" withExtension:@"html" subdirectory:@"TestWebKitAPI.resources"]; }
};

template <typename View>
void AttributedStringTest_Strikethrough::runTest(View view)
{
    NSAttributedString *attrString = attributedString(view, NSMakeRange(0, 5));

    EXPECT_WK_STREQ("Lorem", [attrString string]);
    
    NSDictionary *attributes = [attrString attributesAtIndex:0 effectiveRange:0];
    ASSERT_NOT_NULL([attributes objectForKey:NSStrikethroughStyleAttributeName]);
    ASSERT_TRUE([[attributes objectForKey:NSStrikethroughStyleAttributeName] isKindOfClass:[NSNumber class]]);
    ASSERT_EQ(NSUnderlineStyleSingle, [(NSNumber *)[attributes objectForKey:NSStrikethroughStyleAttributeName] intValue]);
}

TEST_F(AttributedStringTest_Strikethrough, WebKit)
{
    runWebKit1Test();
}

TEST_F(AttributedStringTest_Strikethrough, WebKit2)
{
    runWebKit2Test();
}

} // namespace TestWebKitAPI