# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..13} pypy3 )

inherit distutils-r1

DESCRIPTION="Python client for Neovim"
HOMEPAGE="
	https://github.com/neovim/pynvim/
	https://pypi.org/project/pynvim/
"
SRC_URI="
	https://github.com/neovim/${PN}/archive/${COMMIT_HASH}.tar.gz
		-> ${P}.gh.tar.gz
"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~x86"

RDEPEND="
	>=dev-python/msgpack-0.5.0[${PYTHON_USEDEP}]
	$(python_gen_cond_dep '
		>=dev-python/greenlet-3.0[${PYTHON_USEDEP}]
	' 'python*')
	$(python_gen_cond_dep '
		>=dev-python/typing-extensions-4.5[${PYTHON_USEDEP}]
	' 3.11 3.12)
"
BDEPEND="
	test? (
		app-editors/neovim
		dev-python/pytest-timeout[${PYTHON_USEDEP}]
	)
"

RESTRICT="mirror"

: ${EPYTEST_TIMEOUT:=5}
distutils_enable_tests pytest

python_test() {
	local EPYTEST_DESELECT=(
		# hangs
		test/test_events.py::test_broadcast
	)

	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
	epytest
}

python_prepare_all() {
	sed -e "s/msgpack-python/msgpack/g" -i setup.py || die
	sed -re "s:[\"']pytest-runner[\"'](,|)::" -i setup.py || die
	distutils-r1_python_prepare_all
}
