curator/scripts/PKGBUILD

# Maintainer: Alexander Rosenberg <zanderpkg at pm dot me>

pkgname=curator
pkgver=1
pkgrel=1
pkgdesc="A program for uploading images to Art Museum"
url="https://gitlab.com/zander671/curator"
arch=('i686' 'x86_64')
license=('GPL3')
depends=('ffmpeg')
makedepends=('gradle' 'git')
source=("git+https://gitlab.com/zander671/curator.git")
sha256sums=('SKIP')

pkgver(){
  cd $pkgname
  git rev-list --count HEAD
}

build() {
  cd "$srcdir/$pkgname"
  gradle installDist
}

package() {
  cd "$srcdir/$pkgname"
  mkdir -p "$pkgdir/usr/share"
  cp -r build/install/curator "$pkgdir/usr/share/"
  mkdir -p "$pkgdir/usr/bin"
  ln -fs "/usr/share/curator/bin/curator" "$pkgdir/usr/bin/curator"
  install -m644 -D LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -m644 -D README.md "$pkgdir/usr/share/doc/$pkgname/README"
  install -m644 -D scripts/linux/curator.xpm "$pkgdir/usr/share/pixmaps/curator.xpm"
  install -m644 -D scripts/linux/curator.png "$pkgdir/usr/share/icons/hicolor/48x48/apps/curator.png"
  install -m644 -D scripts/linux/curator.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/curator.svg"
  install -m644 -D scripts/linux/curator.desktop "$pkgdir/usr/share/applications/curator.desktop"
}