TITLE	BOOT  ...  TENEX BOOTSTRAPPER  ...  JMB  ...  4/20/77

	.INSRT MUDSYS;STENEX >

	A=1
	B=2

	LOC	140

START:	HRLZI	A,100001
	MOVE	B,[440700,,SAVFIL]
	GTJFN
	HALTF
	MOVEI	0,(A)			;JFN TO SAVE FILE
	TLZ	A,-1
	MOVE	B,[440000,,240000]
	OPENF
	HALTF
	HRLZI	A,100001
	MOVE	B,[440700,,FILE]
	GTJFN				; JFN TO INTERPRETER
	HALTF
	HRLI	A,400000
	MOVE	BLTPTR,[LOADGO,,B]
	BLT	BLTPTR,BLTPTR
	JRST	B

LOADGO:	GET				; LOAD INTERPRETER
	MOVEI	A,400000
	GEVEC				; CONS STARTING ADDRESS
	JRST	1(B)			; JRST TO START+1 IN INTERPRETER

FILE:	ASCIZ	/<MDL>MDL104.EXE/
SAVFIL:	ASCIZ	/<MDL>MADADV.SAVE/
	BLTPTR=FILE-LOADGO+1

	END	START
